HOWTO

Eigener VBScript Code - Anruferüberprüfung in Datenbank (kb2219)

Die Information in diesem Artikel betrifft die folgenden Produkte:

  • Ab SwyxWare v4.00

[ Zusammenfassung | Information | Referenzen ]


Zusammenfassung

Ab der SwyxWare v4.00 ist es möglich eigenen Skript Code in den Grafischen Skript Editor (GSE) einzufügen. Die Funktionalität des GSE steht Ihnen nur zur Verfügung, wenn Sie das Option Pack - Extended Call Routing lizensiert haben.

Dieser Artikel beschreibt wie man eine einfache Anruferüberprüfung in einer Datenbank (z.B. MS Access) implementiert.

Weitere Artikel dieser Serie:

 

Weitere Informationen zu den Neuerungen im Grafischen Skript Editor finden Sie in dem Artikel:


Information

Installation der Beispielregeln

Laden Sie alle Beispielregeln über den unten angegebenen Link herunter und kopieren Sie die Datein in das Verzeichnis c:\gse_demo Um die Datei CheckCaller.rse in den Call Routing Manager (CRM) bzw. Grafischen Skript Editor (GSE) zu laden, gehen Sie bitte wie folgt vor:

 

  • Starten Sie den Call Routing Manager.
  • Klicken Sie auf Neu...
  • Wählen Sie den Grafischen Skript Editor und klicken Sie auf Ok.
  • Öffnen Sie das Menü Datei | Impotieren... im GSE.
  • Wählen Sie die Datei CheckCaller.rse. Die Regel wird nun importiert und sieht wie folgt aus:

    Grafischer Skript Editor
    Grafischer Skript Editor
    Zum Vergrößern anklicken ...

  • Speichern Sie die Regel über das Menü Datei | Speichern.
  • Schliessen Sie den GSE.
  • Aktivieren Sie die neue Regel durch Verschieben in die rechte Liste im CRM.

    Call Routing Manager
    Call Routing Manager
    Zum Vergrößern anklicken ...

 

Wie das Skript funktioniert

Eigener Skriptcode kann nur in dem Regel Start Block hinzugefügt werden. Alle Konstanten, Variablen und Funktionen die Sie hier definieren stehen Ihnen in allen Blöcken dieses Skriptes zur Verfügung, z.B. im Auswerten Block. Bitte beachten Sie, dass der GSE dem finalen Skript das VBScript Statement option explicit hinzufügt. Dies hat zur Folge, dass Sie alle Variablen innerhalb des Skriptes vor der Benutzung definieren müssen.

Eigenschaften - Regel Start
Eigenschaften - Regel Start
Zum Vergrößern anklicken ...

Um die Rufnummer des ankommenden Rufes in der Datenbank zu überprüfen, verwenden wir einen Auswerten Block. Als Vergleich geben wir lediglich den Name unserer Funktion KnownCallerId mit der Rufnummer der Anrufers an.

Eigenschaften - Check Caller in DB
Eigenschaften - Check Caller in DB
Zum Vergrößern anklicken ...

Diese Funktion liefert Wahr falls die Rufnummer in der Datenbank bekannt ist, andernfalls liefert Sie Falsch. Damit ist sie auch direkt in dem Auswerten Block verwendbar, denn ein Vergleich x = y liefert auch nur Wahr oder Falsch. Für den Fall, dass Wahr zurück geliefert wird, geht es weiter zu dem Ansage abspielen Block welcher einfach nur die Datei Beep.wav abspielt. Andernfalls geht es direkt an das Ende der Regel. Und so sieht der Sktipt Code aus

 

  1. ' CursorTypeEnum Values
  2. Const adOpenForwardOnly = 0
  3. Const adOpenKeyset = 1
  4. Const adOpenDynamic = 2
  5. Const adOpenStatic = 3
  6.  
  7. ' LockTypeEnum Values
  8. Const adLockReadOnly = 1
  9. Const adLockPessimistic = 2
  10. Const adLockOptimistic = 3
  11. Const adLockBatchOptimistic = 4
  12.  
  13. ' CommandTypeEnum Values
  14. Const adCmdUnknown = &H0008
  15. Const adCmdText = &H0001
  16. Const adCmdTable = &H0002
  17. Const adCmdStoredProc = &H0004
  18.  
  19.  
  20. Function KnownCallerId ( callerID )
  21.  
  22.     Dim bReturn
  23.     bReturn = false
  24.  
  25.     Dim sDsn
  26.     sDsn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
  27.         "Data Source=c:\gse_demo\demo.mdb"
  28.  
  29.     ' open connection to database
  30.     Dim db
  31.     Set db = CreateObject("ADODB.Connection")
  32.     db.Open sDsn
  33.  
  34.     ' open recordset
  35.     Dim sSQL
  36.     Dim rs
  37.     sSQL = "select * from callers where callerid = '" & _
  38.         callerID & "'"
  39.  
  40.     Set rs = CreateObject("ADODB.Recordset")
  41.     rs.Open sSQL, db, adOpenDynamic, adLockOptimistic, _
  42.         adCmdText
  43.  
  44.     ' if there are records in recordset,
  45.     ' this caller seems to be known
  46.     bReturn = not rs.EOF
  47.  
  48.     rs.Close
  49.     Set rs = Nothing
  50.  
  51.     db.Close
  52.     Set db = Nothing
  53.  
  54.     KnownCallerId = bReturn
  55.  
  56. End Function

 

Nachdem die Regel aktiviert wurde wird immer wenn ein bekannter Anrufer anruft (in diesem Beispiel ist es der Benutzer mit der Durchwahl 100) ein Piep abgespielt. Andernfalls geschieht nichts. Bitte beachten Sie, dass wir die Regel über den Aufgang Regel übersprungen verlassen. Dies ermöglicht es uns im Anschluss noch weitere Regeln in unserem Callrouting auszuführen.

Hinweise

 

  • Alle Callrouting Skripte, und somit auch der eigene Skript Code, werden unter dem SwyxWare Service Account ausgeführt. Achten Sie also bitte darauf, dass dieser Account die nötigen Rechte hat, die Datei/Datenbank an dem gewünschten Ort zu bearbeiten.

  • In diesem Beispiel wird eine MS Access Datenbank verwendet. Für Demonstrationszwecke ist diese durchaus geeignet, nicht jedoch für Produktionsumgebungen! Verwenden Sie in einer Produktionsumgebung ausschliesslich vollwertige Datenbank wie z.B. den MS SQL Server!

  • Das Skript in diesem Beispiel enthält um es übersichtlich zu halten, keine Fehlerbehandlung. Das heisst, wenn z.B. bei dem Zugriff auf die Datei/Datenbank ein Fehler auftritt, wird dieser nicht abgefangen, sondern führt statt dessen dazu, dass das Skript beendet wird, und der Ruf verloren geht. Sollten Sie das Server Tracing für SvrScript auf Info3 gesetzt haben, so wird die originale Fehlermeldung der Microsoft Script Engine dort protokolliert.

    Um eine eigene Fehlerbehandlung einzufügen müssen Sie zunächst die Standard-Fehlerbehandlung der Script Engine ausschalten:

     

    1. On Error Resume Next

     

    Diese Zeile fügen Sie am Besten als erste Zeile in Ihren Funktionen einen. Nun muss nach jedem Aufruf der Potentiell zu einem Fehler führen kann, eine Fehlerabfrage erfolgen:

     

    1. ' Open connection to Database
    2. db.Open sDsn
    3. If Err <> 0 then
    4.     'do something, e.g.:
    5.     FunctionName = False
    6.     Exit Function
    7. End If

     

  • Neben der in diesem Beispiel gezeigten, sogenannten DSN-less Connection zur Datenbank kann natürlich jede beliebige Datenbank über ODBC angesprochen werden, sofern eine entsprechende ODBC Datenquelle auf dem SwyxServer Rechner konfiguriert wurde. Die nötigen Äderungen im Skript beschränkten sich auf eine einzige Zeile. Anstelle von

     

    1. sDsn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    2.     "Data Source=c:\gse_demo\demo.mdb"

     

    ist lediglich der Name der ODBC Datenquelle anzugeben

     

    1. sDsn = "dsn=MyDatabase"

     

    Sollte die Datenbank eine Anmeldung erfordern, so können die Zugangsdaten ebenfalls in diesem sogenannten Connection String angegeben werden:

     

    1. sDsn = "dsn=MyDatabase;uid=MyName;pwd=MyPassword"

     

    Weitere Beispiele finden Sie über den unter den Referenzen angegebenen Link.

     


Referenzen

Soweit die von uns gelieferte oder/und verwendete Software Open Source Elemente beinhaltet, gelten zusätzlich die unter https://www.swyx.de/open-source einsehbaren zusätzlichen Bedingungen. Welche Produkte aus dem Swyx Portfolio Open Source Elemente beinhalten und welche Open Source Lizenz einschlägig ist, ergibt sich aus der unter folgender URL einsehbaren Liste https://www.swyx.de/open-source.

Informationen anderer Anbieter, die in diesem Artikel zur Verfügung gestellt werden, sollen bei der Suche nach technischen Informationen helfen. Die Inhalte können ohne weitere Ankündigung geändert werden. Swyx garantiert weder für die Güte von Inhalten anderer Anbieter, noch ist Swyx für diese verantwortlich.


Kommentar

Hat Ihnen dieser Artikel weitergeholfen? Kommentieren Sie diesen Artikel



Sollten sich Fragen aus Ihrem Kommentar ergeben, wie können wir Sie erreichen?

E-Mail Adresse (optional)


Hinweis

Dieses Kommentar-Feld steht Ihnen nicht für Support-Anfragen zur Verfügung. Diese richten Sie bitte ausschliesslich an Ihren Swyx Händler bzw. Distributor.


Änderungen

Erstellt: 28.08.2002